source: branches/vendor/trolltech/qt/current/mkspecs/features/resources.prf @ 2

Last change on this file since 2 was 2, checked in by Dmitry A. Kuminov, 12 years ago

Initially imported qt-all-opensource-src-4.5.1 from Trolltech.

File size: 1.2 KB
Line 
1isEmpty(QMAKE_RCC) {
2    win32:QMAKE_RCC = $$[QT_INSTALL_BINS]\rcc.exe
3    else:QMAKE_RCC = $$[QT_INSTALL_BINS]/rcc
4}
5
6isEmpty(RCC_DIR):RCC_DIR = .
7isEmpty(QMAKE_RESOURCE_PREFIX):QMAKE_RESOURCE_PREFIX = /tmp/
8isEmpty(QMAKE_MOD_RCC):QMAKE_MOD_RCC = qrc
9
10resource_combine {
11   rcc.CONFIG += combine
12   rcc.output  = $$RCC_DIR/$${first(QMAKE_MOD_RCC)}_combined$${first(QMAKE_EXT_CPP)}
13} else {
14   rcc.output = $$RCC_DIR/$${first(QMAKE_MOD_RCC)}_${QMAKE_FILE_BASE}$${first(QMAKE_EXT_CPP)}
15}
16!contains(QMAKE_RESOURCE_FLAGS, -root):!isEmpty(QMAKE_RESOURCE_ROOT):QMAKE_RESOURCE_FLAGS += -root $$QMAKE_RESOURCE_ROOT
17!contains(QMAKE_RESOURCE_FLAGS, -name) {
18    resource_combine {
19       isEmpty(QMAKE_RESOURCE_NAME):!isEmpty(TARGET):QMAKE_RESOURCE_NAME = $$TARGET
20       !isEmpty(QMAKE_RESOURCE_NAME):QMAKE_RESOURCE_FLAGS += -name $$QMAKE_RESOURCE_NAME
21    } else {
22       QMAKE_RESOURCE_FLAGS += -name ${QMAKE_FILE_BASE}
23    }
24}
25rcc.commands = "$$QMAKE_RCC" $$QMAKE_RESOURCE_FLAGS "${QMAKE_FILE_IN}" -o "${QMAKE_FILE_OUT}"
26rcc.depend_command = "$$QMAKE_RCC" -list $$QMAKE_RESOURCE_FLAGS "${QMAKE_FILE_IN}"
27rcc.input = RESOURCES
28rcc.variable_out = SOURCES
29rcc.name = RCC ${QMAKE_FILE_IN}
30silent:rcc.commands = @echo rcc "${QMAKE_FILE_IN}" && $$rcc.commands
31QMAKE_EXTRA_COMPILERS += rcc
Note: See TracBrowser for help on using the repository browser.