source: trunk/src/netlabs/macros/swaptext.e@ 3361

/****************************** Module Header *******************************
*
* Module Name: swaptext.e
*
* Copyright (c) Netlabs EPM Distribution Project 2002
*
* $Id: swaptext.e 3361 2018-12-17 19:38:32Z aschn $
*
* ===========================================================================
*
* This file is part of the Netlabs EPM Distribution package and is free
* software.  You can redistribute it and/or modify it under the terms of the
* GNU General Public License as published by the Free Software
* Foundation, in version 2 as it comes in the "COPYING" file of the
* Netlabs EPM Distribution.  This library is distributed in the hope that it
* will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty
* of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
* General Public License for more details.
*
****************************************************************************/

; ---------------------------------------------------------------------------
defc MoveLineUp
   if .last < 2 then
      return
   endif
   SavedAutosave = .autosave
   .autosave = 0
   call psave_mark( SavedMark)

   call NextCmdAltersText()
   getfileid fid
   Line = Max( .line - 1, 1)
   call pset_mark( .line, .line, 1, MAXCOL, 'LINE', fid)
   -- The destination for line mark movement is below the current line.
   -- Therefore go one more line up.
   .lineg = Line - 1  -- Go to line Line - 1 without scrolling
   --call pmove_mark()
   movemark
   .lineg = Line  -- Go to line Line without scrolling
   .line  = Line  -- Scroll when outside of window

   call prestore_mark( SavedMark)
   .autosave = SavedAutosave
   return

; ---------------------------------------------------------------------------
defc MoveLineDown
   if .last < 2 then
      return
   endif
   SavedAutosave = .autosave
   .autosave = 0
   call psave_mark( SavedMark)

   call NextCmdAltersText()
   getfileid fid
   Line = Min( .line + 1, .last)
   call pset_mark( .line, .line, 1, MAXCOL, 'LINE', fid)
   .lineg = Line  -- Go to line Line without scrolling
   --call pmove_mark()
   movemark
   .lineg = Line  -- Go to line Line without scrolling
   .line  = Line  -- Scroll when outside of window

   call prestore_mark( SavedMark)
   .autosave = SavedAutosave
   return

; ---------------------------------------------------------------------------
defc MoveCharLeft
   SavedAutosave = .autosave
   .autosave = 0
   call psave_mark( SavedMark)

   call NextCmdAltersText()
   getfileid fid
   call pset_mark( .line, .line, .col, .col, 'CHAR', fid)
   OldCol = .col
   left
   if .col < OldCol then
      movemark
   endif

   call prestore_mark( SavedMark)
   .autosave = SavedAutosave
   return

; ---------------------------------------------------------------------------
defc MoveCharRight
   SavedAutosave = .autosave
   .autosave = 0
   call psave_mark( SavedMark)

   call NextCmdAltersText()
   getfileid fid
   call pset_mark( .line, .line, .col, .col, 'CHAR', fid)
   OldCol = .col
   right
   right
   if .col > OldCol then
      movemark
   endif

   call prestore_mark( SavedMark)
   .autosave = SavedAutosave
   return

; ---------------------------------------------------------------------------
defc MoveExpressionRight
   SeparatorList = arg( 1)
   call MoveExpr( 'R', arg( 1))

; ---------------------------------------------------------------------------
defc MoveExpressionLeft
   SeparatorList = arg( 1)
   call MoveExpr( 'L', arg( 1))

; ---------------------------------------------------------------------------
defproc MoveExpr
   Direction = upcase( arg( 1))
   if not wordpos( Direction, 'R L') then
      Direction = 'R'
   endif
   SeparatorList = arg( 2)
   if SeparatorList = '' then
      SeparatorList = ' ~`!%^&*()-+=][{}|\:;?/><,''"'\t
   endif

   SavedAutosave = .autosave
   .autosave = 0
   call psave_mark( SavedMark)

   call NextCmdAltersText()
   do once = 1 to 1
      getline LineStr
      CursorCol = .col
      Len = length( LineStr)
      RevLineStr = reverse( LineStr)

      -- Find first expression
      EndCol1 = verify( LineStr, SeparatorList, 'M', .col)
      if EndCol1 = CursorCol then
         'SayError On a separator, move cursor to an expression first.'
         leave
      endif
      EndCol1 = EndCol1 - 1
      if EndCol1 < 1 then
         EndCol1 = Len
      endif

      VerifyStart = Len - CursorCol + 1
      RevEndCol1 = verify( RevLineStr, SeparatorList, 'M', VerifyStart)
      RevEndCol1 = RevEndCol1 - 1
      if RevEndCol1 < 1 then
         RevEndCol1 = Len
      endif
      StartCol1 = Len - RevEndCol1 + 1
      Len1 = EndCol1 - StartCol1 + 1
      Expr1 = substr( LineStr, StartCol1, Len1)

      getfileid fid
      call pset_mark( .line, .line, StartCol1, EndCol1, 'CHAR', fid)

      if Direction = 'R' then
         -- Move right

         -- Find next expression
         StartCol2 = verify( LineStr, SeparatorList, '', EndCol1 + 1)
         if not StartCol2 then
            'SayError No second expression right from cursor found.'
            leave
         endif
         EndCol2 = verify( LineStr, SeparatorList, 'M', StartCol2)
         EndCol2 = EndCol2 - 1
         if EndCol2 < 1 then
            EndCol2 = Len
         endif
         Len2 = EndCol2 - StartCol2 + 1
         Expr2 = substr( LineStr, StartCol2, Len2)
         --dprintf( 'StartCol1 = 'StartCol1', EndCol1 = 'EndCol1', StartCol2 = 'StartCol2', EndCol2 = 'EndCol2 ||
         --   ', ['Expr1'] ['Expr2']')

         .col = StartCol2
         movemark
         call pset_mark( .line, .line, StartCol2, EndCol2, 'CHAR', fid)
         .col = StartCol1
         movemark

         .col = EndCol2 - (EndCol1 - CursorCol)
      else
         -- Move left

         -- Find previous expression
         VerifyStart = Len - StartCol1 + 2
         RevEndCol2 = verify( RevLineStr, SeparatorList, '', VerifyStart)
         if not RevEndCol2 then
            'SayError No second expression left from cursor found.'
            leave
         endif
         EndCol2 = Len - RevEndCol2 + 1
         RevEndCol2 = verify( RevLineStr, SeparatorList, 'M', RevEndCol2)
         RevEndCol2 = RevEndCol2 - 1
         if RevEndCol2 < 1 then
            RevEndCol2 = Len
         endif
         StartCol2 = Len - RevEndCol2 + 1
         Len2 = EndCol2 - StartCol2 + 1
         Expr2 = substr( LineStr, StartCol2, Len2)
         --dprintf( 'StartCol1 = 'StartCol1', EndCol1 = 'EndCol1', StartCol2 = 'StartCol2', EndCol2 = 'EndCol2 ||
         --   ', ['Expr1'] ['Expr2']')

         .col = StartCol2
         movemark
         call pset_mark( .line, .line, StartCol2 + Len1, EndCol2 + Len1, 'CHAR', fid)
         .col = StartCol1 + Len1
         movemark

         .col = StartCol2 + CursorCol - StartCol1
      endif
   enddo

   call prestore_mark( SavedMark)
   .autosave = SavedAutosave
   return